User:Samwilson

Babel user information

en-N	This user has a native understanding of English.

en-GB-N	This user has a native understanding of British English.

nys-0	This user has no knowledge of Nyunga (or understands it with considerable difficulty).

This user is a member of the WikiProject Books.

Western Australian railway stations (with no end dates)

The following query uses these:

Items: railway station (Q55488)   , Western Australia (Q3206)

Properties: instance of (P31)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   , connecting line (P81)   , image (P18)   , end time (P582)  
```
SELECT ?station ?stationLabel ?article ?lgaLabel ?connectingLineLabel ?image ?coords WHERE {
  ?station wdt:P31 wd:Q55488 .
  ?station wdt:P131* wd:Q3206 .
  ?station wdt:P131 ?lga .
  OPTIONAL{
    ?article schema:about ?station .
    ?article schema:isPartOf <https://en.wikipedia.org/>
  } .
  OPTIONAL{ ?station wdt:P625 ?coords } .
  OPTIONAL{ ?station wdt:P81 ?connectingLine } .
  OPTIONAL{ ?station wdt:P18 ?image } .
  MINUS { OPTIONAL{ ?station wdt:P582 ?endDate } } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?stationLabel
```

WA local history GLAMs

These can also be browsed via the Monumental GLAM tool at https://tools.wmflabs.org/monumental-glam/#/list/3206?c=-25.5226:123.2446:5

The following query uses these:

Items: local museum (Q1595639)   , local history archive (Q27032320)   , historical society (Q13723070)   , Western Australia (Q3206)

Properties: instance of (P31)   , located in the administrative territorial entity (P131)   , official website (P856)   , coordinate location (P625)  
```
SELECT DISTINCT ?instanceOfLabel ?item ?itemLabel ?lgaLabel ?website ?coords
WHERE {
  { ?item wdt:P31 wd:Q1595639 }
  UNION { ?item wdt:P31 wd:Q27032320 }
  UNION { ?item wdt:P31 wd:Q13723070 } .
  ?item wdt:P31 ?instanceOf .
  ?item wdt:P131* wd:Q3206 .
  ?item wdt:P131 ?lga .
  OPTIONAL{ ?item wdt:P856 ?website } .
  OPTIONAL{ ?item wdt:P625 ?coords } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
```

Libraries in Australia

The following query uses these:

Items: library (Q7075)   , public library (Q28564)   , academic library (Q856234)   , Australia (Q408)

Properties: instance of (P31)   , country (P17)   , coordinate location (P625)   , image (P18)   , official website (P856)

Features: map (Q24515275)  

#defaultView:Map
SELECT ?library ?libraryLabel ?libraryDescription ?coordinate_location ?image ?website ?layer WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  { ?library wdt:P31 wd:Q7075 }
    UNION { ?library wdt:P31 wd:Q28564 }
    UNION { ?library wdt:P31 wd:Q856234 } .
  ?library wdt:P17 wd:Q408 .
  OPTIONAL { ?library wdt:P625 ?coordinate_location }
  OPTIONAL { ?library wdt:P18 ?image }
  BIND( IF( BOUND(?image), "", "Image needed!" ) AS ?layer )
  OPTIONAL { ?library wdt:P856 ?website }
}

Streets in Fremantle

City of Fremantle and Town of East Fremantle Street Names Index

SELECT ?street ?streetLabel ?streetDescription
  ?osmRelation
  ( GROUP_CONCAT( DISTINCT ?namedAfterLabel; SEPARATOR='; ' ) AS ?namedAfter )
  ?image
  ( GROUP_CONCAT( DISTINCT ?coordinateLocation; SEPARATOR=' ' ) AS ?coordinateLocations )
  ( GROUP_CONCAT( DISTINCT ?locationLabel; SEPARATOR='; ' ) AS ?locations )
  ( GROUP_CONCAT( DISTINCT ?connectsWithLabel; SEPARATOR='; ' ) AS ?connectsWiths )
WHERE {
  # Is a street, road, or alley
  { ?street wdt:P31 wd:Q79007 } UNION { ?street wdt:P31 wd:Q34442 } UNION { ?street wdt:P31 wd:Q1251403 } .
  # In the City of Fremantle
  ?street wdt:P131 wd:Q1455046 .
  OPTIONAL { ?street wdt:P625 ?coordinateLocation }
  OPTIONAL { ?street wdt:P2789 ?connectsWith }
  OPTIONAL { ?street wdt:P402 ?osmRelation }
  OPTIONAL { ?street wdt:P138 ?namedAfter }
  OPTIONAL { ?street wdt:P18 ?image }
  OPTIONAL { ?street wdt:P276 ?location }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" .
    ?street rdfs:label ?streetLabel .
    ?street schema:description ?streetDescription .
    ?namedAfter rdfs:label ?namedAfterLabel .
    ?location rdfs:label ?locationLabel .
    ?connectsWith rdfs:label ?connectsWithLabel .
  }
}
GROUP BY ?street ?streetLabel ?streetDescription ?osmRelation ?image
ORDER BY ?streetLabel

OSM export of street names in a given area.

Wikisource books to download

The following query uses these:

Properties: publication date (P577)  
```
SELECT
  ?item ?itemLabel ?articleTitle ?pubDate
  (URI(CONCAT("https://tools.wmflabs.org/wsexport/tool/book.php?lang=he&format=epub-3&page=", ?articleTitle)) AS ?epubDownload)
WHERE {
  ?item wdt:P577 ?pubDate .
  ?article schema:about ?item .
  ?article schema:name ?articleTitle .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],he". }
  ?article schema:isPartOf <https://he.wikisource.org/>
}
```

Fremantle suburbs

The following query uses these:

Items: suburb of Perth (Q23010647)   , City of Fremantle (Q1455046)

Properties: instance of (P31)   , located in the administrative territorial entity (P131)   , OpenStreetMap relation ID (P402)   , named after (P138)  
```
SELECT ?suburb ?suburbLabel ?OSM_relation_ID ?named_afterLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?suburb wdt:P31 wd:Q23010647.
  ?suburb wdt:P131 wd:Q1455046.
  OPTIONAL { ?suburb wdt:P402 ?OSM_relation_ID. }
  OPTIONAL { ?suburb wdt:P138 ?named_after. }
}
```

Fremantle heritage places

The following query uses these:

Items: City of Fremantle (Q1455046)

Properties: located in the administrative territorial entity (P131)   , inHerit Place Number (P2618)   , located on street (P669)   , OpenStreetMap relation ID (P402)   , named after (P138)   , coordinate location (P625)   , house number (P670)  
```
SELECT ?item ?itemLabel ?inheritId ?streetLabel ?streetNumber ?osmRelation ?namedAfterLabel ?coords WHERE {
  ?item wdt:P131 wd:Q1455046 .
  ?item wdt:P2618 ?inheritId .
  OPTIONAL { ?item wdt:P669 ?street }
  OPTIONAL { ?item p:P669/pq:P670 ?streetNumber }
  OPTIONAL { ?item wdt:P402 ?osmRelation }
  OPTIONAL { ?item wdt:P138 ?namedAfter }
  OPTIONAL { ?item wdt:P625 ?coords }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
```

Geocoding from OpenStreetMap, with OpenRefine: https://gist.github.com/pdbartsch/5987932 (after house numbers are in OSM).

Burial plots at Fremantle cemetery

Search the MCB: https://portal.mcb.wa.gov.au/name-search/

The following query uses these:

Items: human (Q5)   , Fremantle Cemetery (Q5501472)

Properties: instance of (P31)   , place of burial (P119)   , image of grave (P1442)   , burial plot reference (P965)   , coordinate location (P625)  
```
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?image ?plotRef ?plotCoords WHERE {
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P119 wd:Q5501472 .
  OPTIONAL { ?item wdt:P1442 ?image . }
  OPTIONAL { ?item p:P119/pq:P965 ?plotRef . }
  OPTIONAL { ?item p:P119/pq:P625 ?plotCoords . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
```

People 'of' Fremantle

Profiles of 150 Women who Helped Make Western Australia's History

Reflections: Profiles of 150 Women who helped make Western Australian History (Q118878841) was published in 1978 for the state's sesquicentenary. Edited by Daphne Popham (Q118878965).

Query for the above, adding described by source (P1343)Reflections: Profiles of 150 Women who helped make Western Australian History (Q118878841):

The following query uses these:

Items: Reflections: Profiles of 150 Women who helped make Western Australian History (Q118878841)

Properties: described by source (P1343)  
```
SELECT ?item ?itemLabel WHERE {
  ?item wdt:P1343 wd:Q118878841 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
```

WA BDM

Adding references to Western Australian Registry of Births, Deaths, and Marriages (Q42333722).

I've created a tool at wabmd.archives.org.au to track and help add references to people's items.

Example query used to check the required reference for date of birth (P569), place of birth (P19), date of death (P570), and place of death (P20):

The following query uses these:

Properties: date of birth (P569)   , stated in (P248)   , publication date (P577)   , registration district (P5564)   , section, verse, paragraph, or clause (P958)  
```
SELECT ?person ?personLabel ?dateOfBirth ?statedInLabel ?regDistrictLabel (YEAR(?pubDate) AS ?pubYear) ?regNum
WHERE
{
  ?person p:P569 ?dateOfBirthStatement .
  ?dateOfBirthStatement ps:P569 ?dateOfBirth .
  ?dateOfBirthStatement prov:wasDerivedFrom ?refnode .
  ?refnode pr:P248 ?statedIn .
  ?refnode pr:P577 ?pubDate .
  ?refnode pr:P5564 ?regDistrict .
  OPTIONAL{ ?refnode pr:P958 ?regNum } .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
```

Retrieved from "https://www.wikidata.org/w/index.php?title=User:Samwilson&oldid=2256005362"