View source for User:PAC2/Gender diversity

{{User:PAC2/Tabs}}

'''Gender diversity in Wikipedia articles''' is a project about measuring gender diversity in Wikipedia articles. 

Gender bias is a great challenge for the Wikipedia community. Humaniki provides a global overview about gender imbalance in Wikipedia's project<ref>https://whgi.wmflabs.org/</ref>. The share of biographies by gender is a very useful statistic. But we need to go further. What if women are simply not cited in a general article ?

My idea is very simple : takes the list of articles cited in an article (aka blue links), if they concern people,  get the gender using {{P|P21}} and compute gender statistics for the whole article.

Interpretation may be difficult. No one knows the fair share of women in an article. However, when the share of women is really low, we may have forgotten some women and it's worth to have a look at the article and see if we can reduce gender imbalance.

Contributions are welcome. Leave a message on the [[User talk:PAC2/Gender diversity|talk page]] if you want to suggest any improvement.

[[File:Arte do prêmio para o WikidataCon Community Awards 2021 - categoria Gender Equality.png|thumb|This project has been awarded in the [[Wikidata:WikidataCon 2021/Contribute/Community awards|WikidataCon Community Awards 2021]] in the category Gender Equality.]]

== Insights ==
[[File:Share of women in frwiki articles about occupations.png|thumb|Share of women in articles about occupations in Wikipedia in French<ref>https://public.paws.wmcloud.org/User:PAC2/Gender%20diversity%20in%20articles%20about%20occupations%20in%20Wikipedia%20in%20French.ipynb</ref>]]

* [https://public.paws.wmcloud.org/User:PAC2/Gender%20diversity%20in%20academic%20disciplines%20in%20the%20French%20wikipedia.ipynb Gender diversity in academic disciplines in Wikipedia in French]
* [https://public.paws.wmcloud.org/User:PAC2/gender-diversity-academic-disciplines-frwiki.ipynb Gender diversity in academic disciplines in fr.wikipedia.org] (September 2021) with [https://observablehq.com/@pac02/gender-diversity-in-academic-disciplines-in-fr-wikipedia-o visualisation and analysis] 
* [https://public.paws.wmcloud.org/User:PAC2/Gender%20diversity%20in%20articles%20about%20occupations%20in%20Wikipedia%20in%20French.ipynb Gender diversity in professions in Wikipedia in French]
* [https://observablehq.com/@pac02/gender-diversity-in-wikipedia-articles-evidence-from-some?collection=@pac02/Gender-diversity-in-Wikipedia-articles Gender diversity in academic disciplines in Wikipedia in English] 
* [https://observablehq.com/@pac02/gender-diversity-in-wikipedia-articles-focus-on-social-sci?collection=@pac02/gender-diversity-in-wikipedia-articles Gender diversity in Wikipedia articles : Focus on social sciences in Wikipedia in English] 
* [https://observablehq.com/@pac02/gender-diversity-in-wikipedia-articles-focus-on-computer-s?collection=@pac02/gender-diversity-in-wikipedia-articles Gender diversity in Wikipedia articles : Focus on computer sciences in Wikipedia in English]

== Tools ==
* [https://observablehq.com/@pac02/explore-gender-diversity-in-a-single-wikipedia-article JavaScript tool to measure gender diversity in a Wikipedia article] 
* [[:fr:Modèle:Indice de diversité de genre|Template:Gender diversity index]] : a Wikimedia template in fr.wikipedia.org. 
* [[:fr:Utilisateur:PAC2/Chouette|Chouette]] : a script for mobile interface in fr.wikipedia.org which add a link to the gender diversity query at the bottom of the page. 
* [[:fr:Utilisateur:PAC2/Rock your side box|Rock your sidebox]] a script for desktop interface in fr.wikipedia.org which adds a link to the gender diversity query in the side panel.

== Discussions ==
* January 2021: [[:fr:Sujet:W1wi8b13cj6zxmmh|Mesurer la diversité de genre]] [[w:fr:Projet:Les sans pagEs|Les sans pagEs]] 
* December 2021: [[w:Wikipedia_talk:WikiProject_Women_in_Red/Archive_106#Gender_diversity_in_Wikipedia_articles_:_another_way_to_look_at_gender_bias|Gender diversity in Wikipedia articles : another way to look at gender bias]], [[w:Wikipedia:WikiProject Women in Red|Women in Red]]
* December 26, 2021: [[w:fr:Wikipédia:Le Bistro/26 décembre 2021|Mesurer la diversité de genre au sein des articles Wikipédia]]
* [[:en:Wikipedia:Wikipedia Signpost/2022-05-29/In focus|Measuring gender diversity at the article level]],  The Signpost, May 2022

== Methodology ==

=== Measuring gender diversity using Wikimedia API and SPARQL query ===

In this section we explore several SPARQL queries to get gender diversity. 

Those queries can be run directly in [https://public.paws.wmcloud.org/User:PAC2/Gender%20diversity.ipynb Jupyter notebook] using [[Wikidata:PAWS|PAWS]]. 

==== List of all links with gender ====

{{SPARQL
|query = SELECT ?item ?itemLabel ?gender ?genderLabel 
WHERE {
  SERVICE wikibase:mwapi {
     bd:serviceParam wikibase:endpoint "en.wikipedia.org";
                     wikibase:api "Generator";
                     mwapi:generator "links";
                     mwapi:titles "Economics";.
     ?item wikibase:apiOutputItem mwapi:item.
  } 
  FILTER BOUND (?item)
  ?item wdt:P31 wd:Q5 . 
  ?item wdt:P21 ?gender . 
  ?item rdfs:label ?itemLabel filter (lang(?itemLabel) = "en") . 
  ?gender rdfs:label ?genderLabel filter (lang(?genderLabel) = "en") .
}
ORDER BY ?gender 
}} 

==== Simple count ====

{{SPARQL|query = SELECT ?gender ?genderLabel (COUNT(*) AS ?count) 
WHERE {
  SERVICE wikibase:mwapi {
     bd:serviceParam wikibase:endpoint "en.wikipedia.org";
                     wikibase:api "Generator";
                     mwapi:generator "links";
                     mwapi:titles "Economics";.
     ?item wikibase:apiOutputItem mwapi:item.
  } 
  FILTER BOUND (?item)
  ?item wdt:P31 wd:Q5 . 
  ?item wdt:P21 ?gender . 
  ?gender rdfs:label ?genderLabel filter (lang(?genderLabel) = "en") .
}
GROUP BY ?gender ?genderLabel
ORDER BY DESC(?count)
}} 

==== Computing the share of males, females and non binary people ====

This query compute share of women, men, intersexual and non-binary people in the article "Economics". I group together "transgender male" with "male" and "transgender female" with "female".

Caveat : the ROUND function rounds to unity and not to decimal.

{{SPARQL|
query=SELECT 
(SUM(?female) AS ?count_females)
(SUM(?male) AS ?count_males)

(SUM(?nonbinary) AS ?count_nonbinary) 
(SUM(?intersexual) AS ?count_intersexual) 
(COUNT(*) AS ?count) 
(ROUND(100 * ?count_females / ?count) AS  ?share_females) 
(ROUND(100 * ?count_males / ?count) AS  ?share_males) 
(ROUND(100 * ?count_nonbinary / ?count) AS  ?share_nonbinary)
(ROUND(100 * ?count_intersexual / ?count) AS ?share_intersexual)

{
  SERVICE wikibase:mwapi {
     bd:serviceParam wikibase:endpoint "en.wikipedia.org";
                     wikibase:api "Generator";
                     mwapi:generator "links";
                     mwapi:titles "Economics";.
     ?item wikibase:apiOutputItem mwapi:item.
  } 
  FILTER BOUND (?item)
  ?item wdt:P31 wd:Q5 . 
  ?item wdt:P21 ?gender . 
  BIND(IF(?gender IN(wd:Q6581097, wd:Q2449503), 1, 0) AS ?male ) 
  BIND(IF(?gender IN(wd:Q6581072, wd:Q1052281), 1, 0 ) AS ?female)
  BIND(IF(?gender = wd:Q48270, 1, 0) AS ?nonbinary) 
  BIND(IF(?gender = wd:Q1097630, 1,0) AS ?intersexual)
}
}}

==== Comparing different articles ====

{{SPARQL|query =
# This query takes a list of article in Wikipedia, analyse the gender of all entities cited in the article and count the share of males, females and non binary.
# The goal is to measure gender diversity inside wikipedia articles
# Feedback and comments are welcome on my talk page User:PAC2
SELECT ?article
(SUM(?female) AS ?count_females) 
(SUM(?male) AS ?count_males)
(SUM(?nonbinary) AS ?count_nonbinary) 
(SUM(?intersexual) AS ?count_intersexual) 
(COUNT(*) AS ?count) 
(ROUND(100 * ?count_females / ?count) AS  ?share_females) 
(ROUND(100 * ?count_males / ?count) AS  ?share_males) 
(ROUND(100 * ?count_nonbinary / ?count) AS  ?share_nonbinary)
(ROUND(100 * ?count_intersexual / ?count) AS ?share_intersexual)
{
  VALUES ?article {
  "Anthropology"
  "Philosophy"
  "Economics"
  "Sociology"
  "Demography"
  }
  SERVICE wikibase:mwapi {
     bd:serviceParam wikibase:endpoint "en.wikipedia.org";
                     wikibase:api "Generator";
                     mwapi:generator "links";
                     mwapi:titles ?article;.
     ?item wikibase:apiOutputItem mwapi:item.
  } 
  FILTER BOUND (?item)
  ?item wdt:P31 wd:Q5 . 
  ?item wdt:P21 ?gender . 
  BIND(IF(?gender IN(wd:Q6581097, wd:Q2449503), 1, 0) AS ?male ) 
  BIND(IF(?gender IN(wd:Q6581072, wd:Q1052281), 1, 0 ) AS ?female)
  BIND(IF(?gender = wd:Q48270, 1, 0) AS ?nonbinary) 
  BIND(IF(?gender = wd:Q1097630, 1,0) AS ?intersexual)
}
GROUP BY ?article
}}

== Related work ==

{{u|Isaac (WMF)}} has developed something similar with a user script ([[w:User:Isaac (WMF)/link gender]], [[w:User:Isaac (WMF)/link gender.js]]) which calls an API (https://article-gender-data.wmcloud.org/api/v1/out links-details).

[https://gendered-news.imag.fr/genderednews/data/ Gendered News]  is a research project measuring gender diversity in French newspapers. It uses first names to   compute the probability of having a male/female and returns gender counts at the article level.

OpenSexism has created the Wednesday index, a twitter thread which measures each wednesday gender diversity in 26 Wikipedia articles<ref>https://twitter.com/OpenSexism/status/1458841564818513926?t=ikCL4Vj_kI2m4M2UrkymAg&s=19</ref>. OpenSexism has published an article about the wednesday index<ref>https://link.medium.com/64GXFQdPfsb</ref>. 

{{u|Dsp13}} has created a new wiki page to improve gendered citation statistics in Wikipedia : [[:w:User:Dsp13/Gendered citation bias]].

{{Quote|“If you start at any given article on Wikipedia, you're much less likely to eventually reach an article about a woman artist than you are about a male artist – and this was true for women across the board.<ref>https://www.asc.upenn.edu/news-events/news/bridging-wikipedias-gender-gap-one-article-time</ref>”}}

== References ==
{{Reflist}}

== See also ==
* [https://m.youtube.com/watch?v=X9fIf1nFsyw&list=PLix3nF56D5l6J6qswL_m19kdcs35IOik6&index=17 Biais de genre (gender bias)], Wikiconference 2021