Wikidata:Synia:item

Synia : item

All statements with item as a value

PREFIX target: <http://www.wikidata.org/entity/Q263367>

SELECT ?item ?itemLabel ?property ?propertyLabel 
WHERE {
  {
    SELECT ?item ?property {
      hint:Query hint:optimizer "None" .
      ?property wikibase:claim ?p ;
        wikibase:statementProperty ?ps .
      ?st ?ps target:.
      ?item ?p ?st .
    }
    LIMIT 1000
  }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  }
}

Try it!

All statements with item as a qualifier value

PREFIX target: <http://www.wikidata.org/entity/Q263367>

SELECT ?item ?itemLabel ?property ?propertyLabel ?value ?valueLabel ?qualifier ?qualifierLabel WHERE {
  {
    SELECT ?item ?property ?value ?qualifier {
      hint:Query hint:optimizer "None".
      ?qualifier wikibase:qualifier ?pq.
      ?st ?pq target:.
      ?property wikibase:claim ?p;
        wikibase:statementProperty ?ps.
      ?item ?p ?st.
      ?st ?ps ?value.
    }
    LIMIT 1000
  }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
  }
}

Try it!

All statements with item as a reference value

PREFIX target: <http://www.wikidata.org/entity/Q263367>

SELECT ?subject ?subjectLabel ?property ?propertyLabel ?object ?objectLabel WHERE {
  hint:Query hint:optimizer "None".
  ?reference wikibase:reference ?pr.
  ?ref ?pr target:.
  ?statement prov:wasDerivedFrom ?ref.
  ?subject ?p ?statement.
  ?property wikibase:claim ?p;
    wikibase:statementProperty ?ps.
    ?statement ?ps ?object.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en". }
}

Try it!