Piece of queries
#title:Items containing "10.1002/9781444338386"
SELECT ?item WHERE {
SERVICE wikibase:mwapi {
bd:serviceParam wikibase:endpoint "www.wikidata.org";
wikibase:api "Search";
mwapi:srsearch "10.1002/9781444338386";
mwapi:srlimit "max".
?item wikibase:apiOutputItem mwapi:title.
}
}
Items containing "10.1002/9781444338386"
- WPDE :
{{subst:Redundanz|Erster Artikel|Zweiter Artikel}}
dans les deux articles
- WPES :
{{sust:fusionar|nom article}}
dans les deux articles
- WPIT :
{{U|titolo dell'altra pagina|argomento|mese anno}}
sur une page
VIAF used to source dob or dod
[edit]
SELECT DISTINCT ?item ?itemLabel WHERE {
VALUES ?dates { p:P569 p:P570 }
?item ?dates ?statement .
?statement prov:wasDerivedFrom ?ref .
?ref pr:P214 ?viaf .
}
LIMIT 100
Try it!
Articles without journals per year
[edit]
SELECT ?item ?itemLabel ?doi WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q13442814 ;
wdt:P577 "1936-01-01"^^xsd:dateTime ;
wdt:P356 ?doi .
FILTER NOT EXISTS { ?item wdt:P1433 ?journal }
}
LIMIT 1000
Try it!
Qid with ULAN but no VIAF
[edit]
SELECT * WHERE {
?item wdt:P245 ?ulanValue .
?item wdt:P31 ?typeOf .
FILTER NOT EXISTS { ?item wdt:P214 ?viafValue } .
}
Try it!
Book review whose subject isn't an edition
[edit]
SELECT * WHERE {
?item wdt:P31 wd:Q637866 .
?item wdt:P921 ?subject .
MINUS { ?subject wdt:P31 wd:Q3331189 . }
}
Try it!
Edit16 without an SBN
[edit]
SELECT DISTINCT ?item ?itemLabel ?edit16 ?manus WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P5492 ?edit16 .
OPTIONAL { ?item wdt:P8975 ?manus } .
MINUS { ?item wdt:P396 ?sbn} .
}
Try it!
For Wikidata:Gruppo Wikidata per Musei, Archivi e Biblioteche/Concorso/2023/03
Items described by RE without a proper link to the article
[edit]
SELECT ?item ?itemLabel ?REArticle WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item p:P1343 [ps:P1343 wd:Q1138524 ;
pq:P958 ?REArticle ].
}
Try it!
Items described by RE without the reprocity on the article
[edit]
SELECT ?item ?itemLabel ?REArticle WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item p:P1343 [ps:P1343 wd:Q1138524 ;
pq:P805 ?REArticle ].
MINUS {?REArticle wdt:P921 ?item } .
}
Try it!
Ancient or medieval Greek speaking persons with first name which isn't in Greek alphabet
[edit]
SELECT ?item ?itemLabel ?prenomLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?grec {wd:Q35497 wd:Q36387 } .
?item wdt:P1412 ?grec ;
wdt:P735 ?prenom .
FILTER NOT EXISTS { ?item wdt:P31 wd:Q1747829 . }
FILTER NOT EXISTS { ?prenom wdt:P282 wd:Q8216 . }
MINUS { ?item wdt:P1412 wd:Q150 } #français
MINUS { ?item wdt:P1412 wd:Q188 } #allemand
MINUS { ?item wdt:P1412 wd:Q652 } #italien
MINUS { ?item wdt:P1412 wd:Q809 } #polonais
MINUS { ?item wdt:P1412 wd:Q1321 } #espagnol
MINUS { ?item wdt:P1412 wd:Q1860 } #anglais
MINUS { ?item wdt:P1412 wd:Q5146 } #portugais
MINUS { ?item wdt:P1412 wd:Q7737 } #russe
MINUS { ?item wdt:P1412 wd:Q8798 } #ukrainien
MINUS { ?item wdt:P1412 wd:Q9035 } #danois
MINUS { ?item wdt:P1412 wd:Q9056 } #tchèque
MINUS { ?item wdt:P1412 wd:Q9067 } #hongrois
}
ORDER BY ?prenomLabel
Try it!
Ancient Greek speaking persons without a first name
[edit]
SELECT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P1412 wd:Q35497 .
MINUS { ?item wdt:P735 ?prenom} .
}
Try it!
SELECT DISTINCT ?item ?itemLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?identifier {wdt:P8065 wdt:P3576 wdt:P7041 wdt:P11790 wdt:P7168 wdt:P6941 }
?item ?identifier ?something .
FILTER NOT EXISTS { ?item wdt:P11252 ?trismegistos }
}
Try it!
Classical scholars stated as researchers
[edit]
SELECT DISTINCT ?author ?authorLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?journal { wd:Q3290489 wd:Q2166804 wd:Q15754233 wd:Q2366889 wd:Q1679951 }
?article wdt:P1433 ?journal ;
wdt:P50 ?author .
?author wdt:P106 wd:Q1650915 .
}
Try it!
Articles by classicists without a journal
[edit]
SELECT DISTINCT ?article ?articleLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?classicist { wd:Q2468727 wd:Q20873384 wd:Q16267607 wd:Q18916625 wd:Q17598791 }
?article wdt:P31 wd:Q13442814 ;
wdt:P50 ?author .
FILTER NOT EXISTS { ?article wdt:P1433 ?journal } .
?author wdt:P106 ?classicist .
}
Try it!
Completed, to periodically check
[edit]
Click [expand] to view the content
SELECT ?item ?itemLabel ?REArticle WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P1343 ?REArticle .
?REArticle wdt:P361 wd:Q1138524 .
}
Try it!
Ancient Greece or Roman Republic or Empire used as state
[edit]
SELECT ?item ?itemLabel ?property ?countryLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?country { wd:Q2277 wd:Q11772 wd:Q17167} .
VALUES ?property { wdt:P17 wdt:P27 wdt:P710 wdt:P1001 } .
?item ?property ?country .
}
Try it!
Praenomen to create
[edit]
- Cupressenus (+gens)
- Curvius (+gens)
- Navius (+gens)
- Perelius (+gens)
- Probius (+gens)
- Tarrutenius (+gens)
- Vestinus (+gens ; cognomen ?)
- Adventus
- Bassianus
- Berenicianus
- Canus (?)
- Capriolus
- Colo(nus?)
- Decimus(?)
- Ennodius
- Firmus
- Fusinulanus
- Gaianus
- Hirpinus
- Lascivius
- Mamillianus
- Marcianus
- Maximinus
- Montanus
- Passifilus
- Paulinus
- Paenula
- Polemius (?)
- Pompeianus
- Primus
- Rufinianus
- Sulpicianus
- Symmachus
- Tertullus
- Tuccianus
- Vettonianus
- Vetus
- Victorinus
Possible duplicates entries
[edit]
Problematic labelling of nomen
[edit]
RE article without subject