Wikidata:WikiProject Sculpture

Nefertiti Bust (Q582172), 1352–1332 BCE; Neues Museum, Berlin

Welcome to WikiProject Sculpture, where we join forces to improve coverage and quality of the description of sculptures on Wikidata.

Members

Add yourself

1. Juandev (talk) 06:59, 24 September 2019 (UTC)
2. Jimj wpg (talk) 14:28, 13 May 2020 (UTC)
3. Spinster 💬
4. Oravrattas (talk) 11:00, 8 June 2020 (UTC)
5. MartinPoulter (talk) 05:51, 3 August 2024 (UTC)

Subpages

In this Wikidataspace:

Wikidata:

WikiProject Sculpture

• WikiProject Sculpture/Creator/Alexander Calder
• WikiProject Sculpture/Creator/Henry Moore
• WikiProject Sculpture/Genres
• WikiProject Sculpture/Members
• WikiProject Sculpture/Top collections
• WikiProject Sculpture/Top creators
• WikiProject Sculpture/Top creators by number of Dutch streets
• WikiProject Sculpture/Top creators by number of sculptures

Wikidata talk:

WikiProject Sculpture

Showcase queries

Counting

#title:Count of sculptures known to Wikidata
SELECT (COUNT(DISTINCT ?item) AS ?count) WHERE {
?item wdt:P31/wdt:P279* wd:Q860861
}

Count of sculptures known to Wikidata

#title:Wikis with pages about individual sculptures
SELECT ?wiki ?wikinameLabel (COUNT(?site) AS ?count) WITH {SELECT DISTINCT ?item WHERE {
?item wdt:P31/wdt:P279? wd:Q860861 } } AS %toplist WHERE {
INCLUDE %toplist.
?site schema:about ?item ; schema:isPartOf ?wiki .
  OPTIONAL { ?wikiname wdt:P856 ?wiki }
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?wiki ?wikinameLabel ORDER BY DESC(?count)

Wikis with pages about individual sculptures

Image galleries

#title:The most notable sculptures
#defaultView:ImageGrid
SELECT ?item ?itemLabel (SAMPLE(?img) AS ?image) WITH {SELECT DISTINCT ?item WHERE {
?item wdt:P31/wdt:P279? wd:Q860861.
?item wikibase:sitelinks ?sites. } ORDER BY DESC(?sites) LIMIT 100 } AS %toplist WHERE {
INCLUDE %toplist.
?item wdt:P18 ?img.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel

The most notable sculptures

The above query includes a lot of statues and public art with a permanent fixed location. The next query tries to exclude these.

#title:The most notable sculptures without a co-ordinate location
#defaultView:ImageGrid
SELECT ?item ?itemLabel (SAMPLE(?img) AS ?image) WITH {SELECT DISTINCT ?item WHERE {
?item wdt:P31/wdt:P279? wd:Q860861.
  MINUS {?item wdt:P625 []}
?item wikibase:sitelinks ?sites. } ORDER BY DESC(?sites) LIMIT 100 } AS %toplist WHERE {
INCLUDE %toplist.
?item wdt:P18 ?img.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel

The most notable sculptures without a co-ordinate location

Maps

#title:Map of sculptures
#defaultView:Map{"hide": ["?coords", "?image"]}
SELECT ?item ?itemLabel (SAMPLE(?img) AS ?image) ?coords WHERE {
?item wdt:P31/wdt:P279? wd:Q860861;
  wdt:P625 ?coords;
  wdt:P18 ?img
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel ?coords

Map of sculptures

#title:Map of birthplaces of sculptors
#defaultView:Map{"hide": ["?coords"]}
SELECT DISTINCT ?sculptor ?sculptorLabel ?coords WITH {SELECT DISTINCT ?item WHERE {
?item wdt:P31/wdt:P279? wd:Q860861 }  } AS %list WHERE {
INCLUDE %list.
?item wdt:P170 ?sculptor. ?sculptor wdt:P19/wdt:P625 ?coords;
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Map of birthplaces of sculptors

External identifiers

#title:External identifiers used for sculptures
SELECT ?id ?idLabel ?statedLabel (COUNT(?value) AS ?count) WITH {
  SELECT DISTINCT ?item WHERE {
     ?item wdt:P31/wdt:P279? wd:Q860861.
  }
} AS %subquery WHERE {
  INCLUDE %subquery .
  ?id wikibase:propertyType wikibase:ExternalId; wikibase:claim ?p; wikibase:statementProperty ?ps.
  ?item ?p [ ?ps ?value ] . OPTIONAL {?id wdt:P9073 ?stated}
#  ?id rdfs:label ?idlabel FILTER (lang(?idlabel) = "en").
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
} GROUP BY ?id ?idLabel ?statedLabel
ORDER BY DESC(?count)

External identifiers used for sculptures